Add a TCP Echo protocol example

examples/tcp_echo/README.md

@@ -0,0 +1,18 @@
+Ranch TCP Echo
+==============
+
+To compile this example you need rebar in your PATH.
+
+Type the following command:
+```
+$ rebar get-deps compile
+```
+
+You can then start the Erlang node with the following command:
+```
+./start.sh
+```
+
+Then start telnet as indicated and type in a few lines. Be
+aware that there is a timeout of 5 seconds without receiving
+data before the example server disconnects your session.

examples/tcp_echo/rebar.config

@@ -0,0 +1,4 @@
+{deps, [
+	{ranch, ".*",
+		{git, "git://github.com/extend/ranch.git", "master"}}
+]}.

examples/tcp_echo/src/echo_protocol.erl

@@ -0,0 +1,21 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(echo_protocol).
+-export([start_link/4, init/4]).
+
+start_link(ListenerPid, Socket, Transport, Opts) ->
+	Pid = spawn_link(?MODULE, init, [ListenerPid, Socket, Transport, Opts]),
+	{ok, Pid}.
+
+init(ListenerPid, Socket, Transport, _Opts = []) ->
+	ok = ranch:accept_ack(ListenerPid),
+	loop(Socket, Transport).
+
+loop(Socket, Transport) ->
+	case Transport:recv(Socket, 0, 5000) of
+		{ok, Data} ->
+			Transport:send(Socket, Data),
+			loop(Socket, Transport);
+		_ ->
+			ok = Transport:close(Socket)
+	end.

examples/tcp_echo/src/tcp_echo.app.src

@@ -0,0 +1,15 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+{application, tcp_echo, [
+	{description, "Ranch TCP Echo example."},
+	{vsn, "1"},
+	{modules, []},
+	{registered, []},
+	{applications, [
+		kernel,
+		stdlib,
+		ranch
+	]},
+	{mod, {tcp_echo_app, []}},
+	{env, []}
+]}.

examples/tcp_echo/src/tcp_echo.erl

@@ -0,0 +1,12 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+-module(tcp_echo).
+
+%% API.
+-export([start/0]).
+
+%% API.
+
+start() ->
+	ok = application:start(ranch),
+	ok = application:start(tcp_echo).

examples/tcp_echo/src/tcp_echo_app.erl

@@ -0,0 +1,19 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(tcp_echo_app).
+-behaviour(application).
+
+%% API.
+-export([start/2]).
+-export([stop/1]).
+
+%% API.
+
+start(_Type, _Args) ->
+	{ok, _} = ranch:start_listener(tcp_echo, 1,
+		ranch_tcp, [{port, 5555}], echo_protocol, []),
+	tcp_echo_sup:start_link().
+
+stop(_State) ->
+	ok.

examples/tcp_echo/src/tcp_echo_sup.erl

@@ -0,0 +1,22 @@
+%% Feel free to use, reuse and abuse the code in this file.
+
+%% @private
+-module(tcp_echo_sup).
+-behaviour(supervisor).
+
+%% API.
+-export([start_link/0]).
+
+%% supervisor.
+-export([init/1]).
+
+%% API.
+
+-spec start_link() -> {ok, pid()}.
+start_link() ->
+	supervisor:start_link({local, ?MODULE}, ?MODULE, []).
+
+%% supervisor.
+
+init([]) ->
+	{ok, {{one_for_one, 10, 10}, []}}.

examples/tcp_echo/start.sh

@@ -0,0 +1,3 @@
+#!/bin/sh
+erl -pa ebin deps/*/ebin -s tcp_echo \
+	-eval "io:format(\"Run: telnet localhost 5555~n\")."