-module(element_calendar).
%%-author('G-Grand').

-include_lib("nitro/include/calendar.hrl").
-include_lib("nitro/include/nitro.hrl").
-include_lib("nitro/include/event.hrl").

-export([render_element/1]).


render_element(Record) when Record#calendar.show_if == false -> [<<>>];

render_element(Record) ->
  Id = case Record#calendar.postback of
    [] -> Record#calendar.id;
    Postback ->
      ID0 = case Record#calendar.id of
        [] -> nitro:temp_id();
        I -> I
      end,
      nitro:wire(#event{type = click, postback = Postback, target = ID0,
                        source = Record#calendar.source, delegate = Record#calendar.delegate }),
      ID0
  end,
  
  init(Id, Record),
  
  List = [
    %% global
    {<<"accesskey">>, Record#calendar.accesskey},
    {<<"class">>, Record#calendar.class},
    {<<"contenteditable">>,
       case Record#calendar.contenteditable of
         true -> "true";
         false -> "false";
         _ -> []
       end},
    
    {<<"contextmenu">>, Record#calendar.contextmenu},
    {<<"dir">>,
       case Record#calendar.dir of
         ltr -> "ltr";
         rtl -> "rtl";
         auto -> "auto";
         _ -> []
       end},
    
    {<<"draggable">>,
       case Record#calendar.draggable of
         true -> "true";
         false -> "false";
         _ -> []
       end},
    
    {<<"dropzone">>, Record#calendar.dropzone},
    {<<"hidden">>,
       case Record#calendar.hidden of
         true -> "hidden";
         _ -> []
       end},
    
    {<<"id">>, Id},
    {<<"spellcheck">>,
       case Record#calendar.spellcheck of
         true -> "true";
         false -> "false";
         _ -> []
       end},
    
    {<<"style">>, Record#calendar.style},
    {<<"tabindex">>, Record#calendar.tabindex},
    {<<"title">>, Record#calendar.title},
    {<<"translate">>,
       case Record#calendar.contenteditable of
         true -> "yes";
         false -> "no";
         _ -> []
       end},
    
    %% spec
    {<<"autocomplete">>,
       case Record#calendar.autocomplete of
         true -> "on";
         false -> "off";
         _ -> []
       end},
    
    {<<"autofocus">>,
       case Record#calendar.autofocus of
         true -> "autofocus";
         _ -> []
       end},
    
    {<<"disabled">>,
       case Record#calendar.disabled of
         true -> "disabled";
         _ -> []
       end},
    
    {<<"form">>, Record#calendar.form},
    {<<"list">>, Record#calendar.list},
    {<<"name">>, Record#calendar.name},
    {<<"readonly">>,
       case Record#calendar.readonly of
         true -> "readonly";
         _ -> []
       end},
    
    {<<"required">>,
       case Record#calendar.required of
         true -> "required";
         _ -> []
       end},
    
    {<<"step">>, Record#calendar.step},
    {<<"type">>, <<"calendar">>},
    {<<"pattern">>, Record#calendar.pattern},
    {<<"placeholder">>, Record#calendar.placeholder},
    {<<"onkeypress">>, Record#calendar.onkeypress} | Record#calendar.data_fields
  ],

  wf_tags:emit_tag(<<"input">>, nitro:render(Record#calendar.body), List).


init(Id0, #calendar{minDate = Min, maxDate = Max, lang = Lang,
                    format = Form, value = Value, onSelect = SelectFn,
                    disableDayFn = DisDayFn, firstDay = FirstDay, position = Pos,
                    reposition = Repos, yearRange = YearRange} = _Calendar) ->
  ID = nitro:to_list(Id0),
  I18n = case Lang of
    []  -> "clLangs.ua";
    Lang -> "clLangs." ++ nitro:to_list(Lang)
  end,
  
  DefaultDate = case Value of
    {Yv, Mv, Dv} ->
      nitro:f("new Date(~s,~s,~s)", [nitro:to_list(Yv), nitro:to_list(Mv - 1), nitro:to_list(Dv) ]);
    _ -> "''"
  end,
  
  MinDate = case Min of
    {Y, M, D} ->
      nitro:f("new Date(~s,~s,~s)", [nitro:to_list(Y), nitro:to_list(M - 1), nitro:to_list(D) ]);
    _ -> "new Date(2000, 0, 1)"
  end,
  
  MaxDate = case Max of
    {Y1, M1, D1} ->
      nitro:f("new Date(~s,~s,~s)", [nitro:to_list(Y1), nitro:to_list(M1 - 1), nitro:to_list(D1) ]);
    _ -> "new Date(2135, 4, 13)"
  end,
  
  OnSelect = case SelectFn of
    [] -> "null";
    _ -> SelectFn
  end,
  
  DisDay = case DisDayFn of
    [] -> "null";
    _ ->
      nitro:f("function(thisDate){return ~s(thisDate);}", [DisDayFn] )
  end,
  
  Position = case Pos of
    [] -> "bottom left";
    _ -> nitro:to_list(Pos)
  end,
  
  Reposition = case Repos of
    [] -> "true";
    _ -> nitro:to_list(Repos)
  end,
  
  WeekFirstDay = nitro:to_list(FirstDay),
  
  nitro:wire(nitro:f(
    "pickers['~s'] = new Pikaday({"
      "field: document.getElementById('~s'),"
      "i18n: ~s,"
      "defaultDate: ~s,"
      "setDefaultDate: true,"
      "firstDay: ~s,"
      "minDate: ~s,"
      "maxDate: ~s,"
      "format: '~s',"
      "onSelect: ~s,"
      "disableDayFn: ~s,"
      "position: '~s',"
      "reposition: ~s,"
      "yearRange: ~s"
    "});",
    [ID, ID, I18n, DefaultDate, WeekFirstDay, MinDate, MaxDate, Form, OnSelect, DisDay, Position, Reposition, nitro:to_list(YearRange) ] )).