cowboy/src/cowboy_acceptor.erl

%% Copyright (c) 2011, Loïc Hoguin <essen@dev-extend.eu>
%%
%% Permission to use, copy, modify, and/or distribute this software for any
%% purpose with or without fee is hereby granted, provided that the above
%% copyright notice and this permission notice appear in all copies.
%%
%% THE SOFTWARE IS PROVIDED "AS IS" AND THE AUTHOR DISCLAIMS ALL WARRANTIES
%% WITH REGARD TO THIS SOFTWARE INCLUDING ALL IMPLIED WARRANTIES OF
%% MERCHANTABILITY AND FITNESS. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR
%% ANY SPECIAL, DIRECT, INDIRECT, OR CONSEQUENTIAL DAMAGES OR ANY DAMAGES
%% WHATSOEVER RESULTING FROM LOSS OF USE, DATA OR PROFITS, WHETHER IN AN
%% ACTION OF CONTRACT, NEGLIGENCE OR OTHER TORTIOUS ACTION, ARISING OUT OF
%% OR IN CONNECTION WITH THE USE OR PERFORMANCE OF THIS SOFTWARE.

-module(cowboy_acceptor).
-export([start_link/4]). %% API.
-export([acceptor/4]). %% Internal.

-include("include/types.hrl").

%% API.

-spec start_link(LSocket::socket(), Transport::module(),
	Protocol::module(), Opts::term()) -> {ok, Pid::pid()}.
start_link(LSocket, Transport, Protocol, Opts) ->
	Pid = spawn_link(?MODULE, acceptor, [LSocket, Transport, Protocol, Opts]),
	{ok, Pid}.

%% Internal.

-spec acceptor(LSocket::socket(), Transport::module(),
	Protocol::module(), Opts::term()) -> no_return().
acceptor(LSocket, Transport, Protocol, Opts) ->
	case Transport:accept(LSocket) of
		{ok, CSocket} ->
			{ok, Pid} = supervisor:start_child(cowboy_protocols_sup,
				[CSocket, Transport, Protocol, Opts]),
			Transport:controlling_process(CSocket, Pid);
		{error, _Reason} ->
			%% @todo Probably do something here. If the socket was closed,
			%%       we may want to try and listen again on the port?
			ignore
	end,
	?MODULE:acceptor(LSocket, Transport, Protocol, Opts).